Find UserName and Computer Name

Public Function sCurrentUserName() As String
  sCurrentUserName = CreateObject("wscript.network").UserName
End Function

Function sComputerName() As String
  sComputerName = CreateObject("wscript.network").Computername
End Function

Find VBA Version

Public Function VBA_Version() As String
  VBA_Version = Application.VBE.Version ' less information, but faster
End Function

Computer Information

Public Function CompuInfo() As Variant
  Dim arrCompuInfo(1 To 3)   As String
  Dim myWMI As Object, myObj As Object, Itm
  Set myWMI = GetObject("winmgmts:\\.\root\cimv2")
  Set myObj = myWMI.ExecQuery("Select * from Win32_ComputerSystem", , 48)
  For Each Itm In myObj
    arrCompuInfo(1) = Itm.Domain
    arrCompuInfo(2) = Itm.Manufacturer
    arrCompuInfo(3) = Itm.Model
    Debug.Print arrCompuInfo(1) & arrCompuInfo(2) & arrCompuInfo(3)
  Next
  CompuInfo = arrCompuInfo()
End Function

Find Windows Operating System

Public Function OSInfo() As Variant
  Dim arrOSInfo(1 To 3)   As String
  Dim myWMI As Object, myObj As Object, Itm
  Set myWMI = GetObject("winmgmts:\\.\root\cimv2")
  Set myObj = myWMI.ExecQuery("Select * from Win32_OperatingSystem", , 48)
  For Each Itm In myObj
    arrOSInfo(1) = Itm.Caption 'OS
    arrOSInfo(2) = Itm.BuildNumber 'OS Build
'    arrOSInfo(2) = Itm.CSDVersion '
    arrOSInfo(3) = Itm.Version '
    Debug.Print arrOSInfo(1) & "-" & arrOSInfo(2) & "-" & arrOSInfo(3) ' & arrOSInfo(4)
  Next
  OSInfo = arrOSInfo()
End Function

Find MAC Address of computer

Public Function MAC_Address() As String
    Dim myWMI As Object, myObj As Object, Itm
    Set myWMI = GetObject("winmgmts:\\.\root\cimv2")
    Set myObj = myWMI.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")
    For Each Itm In myObj
      MAC_Address = Itm.MACAddress
      Debug.Print MAC_Address
      Exit Function
    Next
End Function

Find my computer IP Address

Public Function getMyIP()
    Dim myWMI As Object, myObj As Object, Itm
    Set myWMI = GetObject("winmgmts:\\.\root\cimv2")
    Set myObj = myWMI.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")
    For Each Itm In myObj
      getMyIP = Itm.IPAddress(0)
      Debug.Print getMyIP
      Exit Function
    Next
End Function